incipit  ::= clef timesignature? keysignature? separator musicalcontent

clef     ::= '%' shape ( '-' | '+' ) DIGIT

keysignature
         ::= '$' ( ( 'x' | 'b' ) notename+ ( '[' ( 'x' | 'b' )? notename+ ']' )? | '[' ( 'x' | 'b' )? notename+ ']' )

timesignature
         ::= '@' meter ( ' ' meter )*

meter    ::= ( 'c' | 'o' ) ( '.' | '/' )? fraction?
           | fraction

fraction ::= number ( '/' number )?

gracenote
         ::= 'g' notepropschange* note
           | 'q' notepropschange* note
           | 'q' 'q' items 'r'

octave   ::= OCTAVE7
           | OCTAVE6
           | OCTAVE5
           | OCTAVE4
           | OCTAVE3
           | OCTAVE2
           | OCTAVE1

rhythmicvalue
         ::= figure '.'*

figure   ::= DIGIT

accidental
         ::= 'x'
           | 'bb'
           | 'b'
           | 'xx'
           | 'n'

musicalcontent
         ::= bar ( barlines bar )* barlines?

bar      ::= items
           | 'i'
           | '=' number?

items    ::= item+

clefkeytimechange
         ::= ( clef | timesignature | keysignature )+ ' '

item     ::= clefkeytimechange
           | irregulargroup
           | triplet
           | notes
           | repetgroup
           | notepropschange

repetgroup
         ::= '!' items '!' 'f'+

triplet  ::= '(' items ')'

irregulargroup
         ::= figure? '(' items ';' number ')'

notepropschange
         ::= octave
           | rhythmicvalue
           | accidental

notes    ::= note ( '^' notepropschange* note )*
           | rest
           | beaming

beaming  ::= '{' items '}'

note     ::= gracenote
           | notevalue
           | notefermata

notefermata
         ::= '(' notevalue ')'

rest     ::= restvalue
           | restfermata

restfermata
         ::= '(' restvalue ')'

notevalue
         ::= notename notesuffix? '.'*

restvalue
         ::= '-'

notesuffix
         ::= 't' slur?
           | slur 't'?

slur     ::= '+'

barlines ::= '/'
           | '/' '/'
           | '/' '/' ':'
           | ':' '/' '/'
           | ':' '/' '/' ':'

shape    ::= 'g'
           | NOTENAMES

notename ::= NOTENAMES

number   ::= DIGIT+

separator
         ::= ( ' ' | '?' | ';' )+

DIGIT    ::= [0-9]

OCTAVE7  ::= "'" "'" "'" "'"

OCTAVE6  ::= "'" "'" "'"

OCTAVE5  ::= "'" "'"

OCTAVE4  ::= "'"

OCTAVE1  ::= ',' ',' ','

OCTAVE2  ::= ',' ','

OCTAVE3  ::= ','

NOTENAMES
         ::= [A-G]

TAB      ::= #x0009

EOL      ::= #x000A
           | #x000D